Comment utiliser les fonctions logiques dans Excel: IF, AND, OR, XOR, NOT

Les fonctions logiques sont parmi les plus populaires et les plus utiles d’Excel. Ils peuvent tester des valeurs dans d’autres cellules et effectuer des actions en fonction du résultat du test. Cela nous aide à automatiser les tâches dans nos feuilles de calcul.

Comment utiliser la fonction IF

La fonction IF est la fonction logique principale d’Excel et est, par conséquent, celle à comprendre en premier. Il apparaîtra plusieurs fois tout au long de cet article.

Jetons un coup d’œil à la structure de la fonction IF, puis voyons quelques exemples de son utilisation.

La fonction IF accepte 3 bits d’information:

=IF(logical_test, [value_if_true], [value_if_false])
  • Test de logique: C’est la condition pour la fonction à vérifier.
  • value_if_true: Action à effectuer si la condition est remplie ou vraie.
  • value_if_false: Action à effectuer si la condition n’est pas remplie ou est fausse.

Opérateurs de comparaison à utiliser avec les fonctions logiques

Lors de l’exécution du test logique avec des valeurs de cellule, vous devez vous familiariser avec les opérateurs de comparaison. Vous pouvez voir une ventilation de ceux-ci dans le tableau ci-dessous.

Opérateurs de comparaison pour les fonctions logiques

Voyons maintenant quelques exemples en action.

Exemple de fonction IF 1: valeurs de texte

Dans cet exemple, nous voulons tester si une cellule est égale à une phrase spécifique. La fonction IF n’est pas sensible à la casse et ne prend donc pas en compte les majuscules et les minuscules.

La formule suivante est utilisée dans la colonne C pour afficher «Non» si la colonne B contient le texte «Terminé» et «Oui» s’il contient autre chose.

=IF(B2="Completed","No","Yes")

Fonction IF pour tester les valeurs de texte

Bien que la fonction IF ne respecte pas la casse, le texte doit correspondre exactement.

Exemple de fonction IF 2: valeurs numériques

La fonction IF est également idéale pour comparer des valeurs numériques.

Dans la formule ci-dessous, nous testons si la cellule B2 contient un nombre supérieur ou égal à 75. Si tel est le cas, nous affichons le mot «Réussir» et sinon le mot «Échec».

=IF(B2>=75,"Pass","Fail")

Si condition avec des valeurs numériques

La fonction IF est bien plus que simplement afficher un texte différent sur le résultat d’un test. Nous pouvons également l’utiliser pour exécuter différents calculs.

Dans cet exemple, nous voulons donner une remise de 10% si le client dépense une certaine somme d’argent. Nous utiliserons 3 000 £ comme exemple.

=IF(B2>=3000,B2*90%,B2)

Formule conditionnelle à l'aide de la fonction IF

La partie B2 * 90% de la formule est un moyen de soustraire 10% de la valeur de la cellule B2. Il existe de nombreuses façons de procéder.

L’important est que vous puissiez utiliser n’importe quelle formule dans le value_if_true ou value_if_false sections. Et exécuter différentes formules en fonction des valeurs d’autres cellules est une compétence très puissante à avoir.

Exemple de fonction IF 3: valeurs de date

Dans ce troisième exemple, nous utilisons la fonction IF pour suivre une liste de dates d’échéance. Nous voulons afficher le mot «En retard» si la date de la colonne B est dans le passé. Mais si la date est dans le futur, calculez le nombre de jours jusqu’à la date d’échéance.

La formule ci-dessous est utilisée dans la colonne C. Nous vérifions si la date d’échéance dans la cellule B2 est inférieure à la date du jour (la fonction AUJOURD’HUI renvoie la date du jour à partir de l’horloge de l’ordinateur).

=IF(B2<TODAY(),"Overdue",B2-TODAY())

Tester si les dates sont dues

Que sont les formules IF imbriquées?

Vous avez peut-être déjà entendu parler du terme IF imbriquées. Cela signifie que nous pouvons écrire une fonction IF dans une autre fonction IF. Nous pouvons vouloir faire cela si nous avons plus de deux actions à effectuer.

En relation :  Comment réparer l'arrêt de Windows 10 au lieu de se mettre en veille ou d'hiberner

Une fonction IF est capable d’effectuer deux actions (le value_if_true et value_if_false ). Mais si nous intégrons (ou imbriquons) une autre fonction IF dans le value_if_false section, nous pouvons alors effectuer une autre action.

Prenons cet exemple où nous voulons afficher le mot «Excellent» si la valeur de la cellule B2 est supérieure ou égale à 90, afficher «Bon» si la valeur est supérieure ou égale à 75 et afficher «Médiocre» si autre chose .

=IF(B2>=90,"Excellent",IF(B2>=75,"Good","Poor"))

Nous avons maintenant étendu notre formule au-delà de ce qu’une seule fonction IF peut faire. Et vous pouvez imbriquer davantage de fonctions IF si nécessaire.

Notez les deux crochets fermants à la fin de la formule – un pour chaque fonction IF.

Il existe des formules alternatives qui peuvent être plus propres que cette approche IF imbriquée. Une alternative très utile est la fonction SWITCH dans Excel.

Les fonctions logiques AND et OR

Les fonctions ET et OU sont utilisées lorsque vous souhaitez effectuer plusieurs comparaisons dans votre formule. La fonction IF seule ne peut gérer qu’une seule condition, ou comparaison.

Prenons un exemple où nous actualisons une valeur de 10% en fonction du montant qu’un client dépense et depuis combien d’années ils sont clients.

À elles seules, les fonctions AND et OR renverront la valeur TRUE ou FALSE.

La fonction AND renvoie VRAI uniquement si toutes les conditions sont remplies, et sinon renvoie FAUX. La fonction OR renvoie TRUE si une ou toutes les conditions sont remplies, et renvoie FALSE uniquement si aucune condition n’est remplie.

Ces fonctions peuvent tester jusqu’à 255 conditions, elles ne sont donc certainement pas limitées à deux conditions comme cela est démontré ici.

Vous trouverez ci-dessous la structure des fonctions ET et OU. Ils sont écrits de la même manière. Remplacez simplement le nom ET par OU. C’est juste leur logique qui est différente.

=AND(logical1, [logical2] ...)

Voyons un exemple des deux évaluant deux conditions.

AND Exemple de fonction

La fonction ET est utilisée ci-dessous pour tester si le client dépense au moins 3 000 £ et est client depuis au moins trois ans.

=AND(B2>=3000,C2>=3)

Fonction AND dans Excel

Vous pouvez voir qu’il renvoie FALSE pour Matt et Terry car bien qu’ils répondent tous les deux à l’un des critères, ils doivent répondre à la fois à la fonction AND.

Exemple de fonction OR

La fonction OU est utilisée ci-dessous pour tester si le client dépense au moins 3000 £ ou s’il est client depuis au moins trois ans.

=OR(B2>=3000,C2>=3)

La fonction logique OR

Dans cet exemple, la formule renvoie TRUE pour Matt et Terry. Seules Julie et Gillian échouent dans les deux conditions et renvoient la valeur FALSE.

Utilisation de AND et OR avec la fonction IF

Étant donné que les fonctions AND et OR renvoient la valeur TRUE ou FALSE lorsqu’elles sont utilisées seules, il est rare de les utiliser seules.

Au lieu de cela, vous les utiliserez généralement avec la fonction IF ou dans une fonctionnalité Excel telle que le formatage conditionnel ou la validation des données pour effectuer une action rétrospective si la formule est évaluée à TRUE.

Dans la formule ci-dessous, la fonction ET est imbriquée dans le test logique de la fonction IF. Si la fonction ET renvoie VRAI, 10% sont déduits du montant de la colonne B; sinon, aucune remise n’est accordée et la valeur de la colonne B est répétée dans la colonne D.

=IF(AND(B2>=3000,C2>=3),B2*90%,B2)

Formule Excel avec fonctions IF et AND

La fonction XOR

En plus de la fonction OR, il existe également une fonction OR exclusive. C’est ce qu’on appelle la fonction XOR. La fonction XOR a été introduite avec la version Excel 2013.

Cette fonction peut demander un certain effort à comprendre, un exemple pratique est donc présenté.

En relation :  Comment faire apparaître les signets Chrome Mobile sur le bureau Chrome

La structure de la fonction XOR est la même que celle de la fonction OR.

=XOR(logical1, [logical2] ...)

Lors de l’évaluation de seulement deux conditions, la fonction XOR renvoie:

  • TRUE si l’une des conditions est évaluée à TRUE.
  • FALSE si les deux conditions sont TRUE ou qu’aucune condition n’est TRUE.

Cela diffère de la fonction OR car cela renverrait TRUE si les deux conditions étaient TRUE.

Cette fonction devient un peu plus déroutante lorsque plus de conditions sont ajoutées. Ensuite, la fonction XOR renvoie:

  • VRAI si un impair nombre de conditions renvoie VRAI.
  • FALSE si un même nombre de conditions donne VRAI, ou si tout les conditions sont FAUX.

Regardons un exemple simple de la fonction XOR.

Dans cet exemple, les ventes sont réparties sur deux moitiés de l’année. Si un vendeur vend 3000 £ ou plus dans les deux moitiés, il se voit attribuer la norme Gold. Ceci est réalisé avec une fonction AND avec IF comme précédemment dans l’article.

Mais s’ils vendent 3000 £ ou plus dans l’une ou l’autre moitié, nous voulons leur attribuer le statut Silver. S’ils ne vendent pas 3000 £ ou plus dans les deux, rien.

La fonction XOR est parfaite pour cette logique. La formule ci-dessous est entrée dans la colonne E et montre la fonction XOR avec IF pour afficher «Oui» ou «Non» uniquement si l’une ou l’autre des conditions est remplie.

=IF(XOR(B2>=3000,C2>=3000),"Yes","No")

La fonction XOR dans Excel

La fonction NOT

La fonction logique finale à discuter dans cet article est la fonction NOT, et nous avons laissé la plus simple pour la fin. Bien que parfois, il puisse être difficile de voir les utilisations «réelles» de la fonction au début.

La fonction NOT inverse la valeur de son argument. Donc, si la valeur logique est TRUE, elle renvoie FALSE. Et si la valeur logique est FALSE, elle retournera TRUE.

Cela sera plus facile à expliquer avec quelques exemples.

La structure de la fonction NOT est;

=NOT(logical)

Exemple de fonction NOT 1

Dans cet exemple, imaginons que nous ayons un siège social à Londres, puis de nombreux autres sites régionaux. Nous voulons afficher le mot «Oui» si le site est autre chose que Londres, et «Non» s’il s’agit de Londres.

La fonction NOT a été imbriquée dans le test logique de la fonction IF ci-dessous pour inverser le résultat TRUE.

=IF(NOT(B2="London"),"Yes","No")

Ceci peut également être réalisé en utilisant l’opérateur logique NOT de <>. Voici un exemple.

=IF(B2<>"London","Yes","No")

Exemple de fonction NOT 2

La fonction NOT est utile lorsque vous travaillez avec des fonctions d’information dans Excel. Il s’agit d’un groupe de fonctions dans Excel qui vérifient quelque chose et retournent TRUE si la vérification est réussie et FALSE si ce n’est pas le cas.

Par exemple, la fonction ISTEXT vérifie si une cellule contient du texte et retourne TRUE si c’est le cas et FALSE si ce n’est pas le cas. La fonction NOT est utile car elle peut inverser le résultat de ces fonctions.

Dans l’exemple ci-dessous, nous souhaitons payer à un vendeur 5% du montant de la vente incitative. Mais s’ils n’ont rien vendu, le mot «Aucun» est dans la cellule et cela produira une erreur dans la formule.

La fonction ISTEXT permet de vérifier la présence de texte. Cela retourne TRUE s’il y a du texte, donc la fonction NOT inverse cela en FALSE. Et le FI effectue son calcul.

=IF(NOT(ISTEXT(B2)),B2*5%,0)

Exemple de fonction NOT 2

La maîtrise des fonctions logiques vous donnera un gros avantage en tant qu’utilisateur Excel. Pouvoir tester et comparer les valeurs dans les cellules et effectuer différentes actions en fonction de ces résultats est très utile.


Cet article a couvert les meilleures fonctions logiques utilisées aujourd’hui. Les versions récentes d’Excel ont vu l’introduction de plus de fonctions ajoutées à cette bibliothèque, telles que la fonction XOR mentionnée dans cet article. Rester à jour avec ces nouveaux ajouts vous gardera en tête de la foule.

Moyens Staff
Moyens I/O Staff vous a motivé, donner des conseils sur la technologie, le développement personnel, le style de vie et des stratégies qui vous aider.