Comment défragmenter parfaitement vos disques durs avec MyDefrag

Les principaux composants des disques durs sont leurs plateaux rotatifs et les têtes qui lisent et écrivent des données dessus. La partie extérieure de ces plateaux en forme de disque, grâce à ce que la physique nous enseigne, a une accélération linéaire plus rapide. De plus, il y a un coût de performance perçu lorsque les données sont réparties sur toute leur surface.

MyDefrag est peut-être à moitié éteint, mais il reste le seul programme de ce type qui peut optimiser votre disque dur exactement comme vous le souhaitez. Comme tous les défragmenteurs, il réorganise toutes les parties de vos fichiers, les regroupe, corrige les faibles performances lorsqu’elles sont réparties sur toute la surface. Il vous permet également de configurer des zones, en plaçant vos fichiers les plus importants dans la région externe la plus rapide de la surface du disque dur. Vous n’avez qu’à lui dire ce qui se passe où à travers un simple script.

Localisez, téléchargez et installez MyDefrag

Malheureusement, MyDefrag n’est plus supporté de nos jours et son site officiel est mort. Vous pouvez toujours le trouver, cependant, sur des sites d’hébergement de logiciels populaires, comme FichierHippo et MajorGeeks.

Téléchargez et installez la dernière version du programme, MyDefrag 4.3.1. Acceptez toutes les valeurs par défaut pendant l’installation et assurez-vous que « Sélectionnez et activez l’économiseur d’écran MyDefrag » est désélectionné.

Créer un nouveau script

Vous ne contrôlez pas le fonctionnement de MyDefrag via une interface graphique ou des options de ligne de commande – cela se fait avec des scripts simples. Repérez le sous-dossier scripts, qui existe à cet effet dans son répertoire d’installation.

Faites un clic droit dans ce répertoire et créez un nouveau fichier TXT vierge. Donnez-lui le nom que vous voulez, mais changez son extension en « MyD », la valeur par défaut pour les scripts MyDefrag. Ensuite, ouvrez-le dans votre éditeur de texte préféré.

Introduction au scénario

Nous utiliserons les fichiers existants comme base pour un script qui optimise un disque dur rempli de jeux, en plaçant les fichiers qui affectent leurs performances plus que d’autres dans les parties les plus rapides de la surface du disque, en déplaçant les moins essentiels et pas fréquemment. accès aux données à l’autre extrémité.

La première partie de votre script devrait configurer les choses comme suit. Notez que vous devez placer chaque paramètre et commande sur une nouvelle ligne individuelle. Notez également que nous utiliserons des commentaires dans le code – ils commencent par « // » – pour expliquer les éléments les plus cryptiques de notre script.

Title("Title of your script")
Description("Short description of your script")
WriteLogfile("MyDefrag.log","LogHeader")
VolumeSelect
CommandlineVolumes()
VolumeActions
AppendLogfile("MyDefrag.log","LogBefore")

Configurez votre première zone

En divisant la surface du disque dur en zones, MyDefrag vous permet de placer des fichiers et des dossiers spécifiques sur les parties de sa surface qui fonctionnent mieux ou moins bien.

Configurez les zones en sélectionnant ce qui doit y entrer :

// Zone 1 - Non-important, slow files
FileSelect // Select specific files.
  !include "file_list.txt"! // Select the files defined in file_list.txt.
FileActions // What MyDefrag will do with those files.
  MoveToEndOfDisk() // Move them to slower portion of the HDD since they are the unimportant ones
  AddGap(ZoneEnd + VolumeFree * 0.1 // Add a 0.1% size gap between that zone and the next one
FileEnd // End file selection for the specific zone

Configurer plus de zones

MyDefrag ne peut regrouper vos fichiers, comme les autres défragmenteurs, que si vous ne configurez aucune zone, mais vous passerez à côté de tout l’intérêt de son utilisation.

Nous avons mis en place plus de zones comme suit :

// Zone 2: Put directories together,  for quicker listing of the HDD's contents - same syntax as before
FileSelect 
  Directory(yes) // Define that we want to select directories, not files.
FileActions
  SortByName(Ascending) // Sort them by alphabetical order.
  AddGap(ZoneEnd + VolumeFree * 0.05)
FileEnd
 
// Zone 3: Typical, popular "game filetypes", for quicker game launching
FileSelect
Filename("_.exe")
OR Filename("_.dll")
OR Filename("_.ini")
OR Filename("_.conf")
OR Filename("_.cfg")
OR Filename("_.bat")
OR Filename("_.ico")
FileActions
  SortByName(Ascending)
  AddGap(ZoneEnd + VolumeFree * 0.1)
FileEnd
 
// Zone 4: Place the MFT and other special NTFS files right after our most important files
FileSelect
  SelectNtfsSystemFiles(yes)
FileActions
  PlaceNtfsSystemFiles(Ascending,MftSize * 0.01) // Move the selected NTFS system files and set the MFT to a %0.01 size.
  AddGap(ZoneEnd + VolumeFree * 0.01)
FileEnd
 
// Zone 5: Recently accessed files (for better performance of last games played).
FileSelect
  LastAccessEnabled(yes) and LastAccess(60 days ago,now)
FileActions
  SortByName(Ascending)
  AddGap(ZoneEnd + VolumeFree * 0.3)
FileEnd
 
// Zone 6: all other files.
FileSelect
  all
FileActions
  SortByName(Ascending)
  AddGap(ZoneEnd + VolumeFree)
FileEnd

Scénario final

Ce qui suit est l’intégralité du script final. N’hésitez pas à le copier et à le coller dans votre propre script, puis à le modifier à votre guise.

Title("Make Tech Easier's Games HDD Monthly")
Description("Optimize Game HDDs by moving temp, downloading, and non-important gaming-related files and directories to its end, leaving the faster HDD space for more important stuff.")
 
// Write the header to the logfile. See the "Settings.MyD" file for the definition of the "LogHeader" string.
WriteLogfile("MyDefrag.log","LogHeader")
 
// Select and process the volumes one by one.
VolumeSelect
  CommandlineVolumes()
VolumeActions
 
// Write the "before" statistics to the logfile. See the "Settings.MyD" file for the definition of the "LogBefore" string.
  AppendLogfile("MyDefrag.log","LogBefore")
 
// Zone 1 - Place Non-important, temp and ultra-large files at the end of the disk.
  FileSelect
    !include "file_list.txt"!
  FileActions
    MoveToEndOfDisk()
    AddGap(ZoneEnd + VolumeFree * 0.1)
  FileEnd
 
// Zone 2: Directories.
  FileSelect
    Directory(yes)
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree * 0.05)
  FileEnd
 
// Zone 3: Main Game Files (for quicker game launch).
  FileSelect
    Filename("*.exe")
	OR Filename("*.dll")
	OR Filename("*.ini")
	OR Filename("*.conf")
	OR Filename("*.cfg")
	OR Filename("*.BAT")
	OR Filename("*.ico")
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree * 0.1)
  FileEnd
 
//Zone 4: Place the MFT and some other special NTFS files.
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    PlaceNtfsSystemFiles(Ascending,MftSize * 0.01)
    AddGap(ZoneEnd + VolumeFree * 0.01)
  FileEnd
 
// Zone 5: Recently accessed files (for better performance of last games played).
  FileSelect
    LastAccessEnabled(yes) and LastAccess(60 days ago,now)
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree * 0.3)
  FileEnd
 
// Zone 6: all other files.
  FileSelect
    all
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree)
  FileEnd
 
// Write the "after" statistics to the logfile. See the "Settings.MyD" file for the definition of the "LogAfter" string.
  AppendLogfile("MyDefrag.log","LogAfter")
 
VolumeEnd
 
// Write the footer to the logfile. See the "Settings.MyD" file for the definition of the "LogFooter" string.
AppendLogfile("MyDefrag.log","LogFooter")

Créer une liste de fichiers de faible priorité

Rappelez-vous comment nous avons dit à notre script de prendre en compte une liste de fichiers de faible priorité, au format TXT, avant d’organiser nos fichiers ? Il est maintenant temps de créer ce fichier.

Cliquez avec le bouton droit sur le dossier des scripts et créez un nouveau fichier TXT vierge. Nommez-le « file_list.txt » – le même nom de fichier que nous avons utilisé dans le script lui-même.

Voici un exemple de liste que vous pouvez copier et utiliser. Remplacez les répertoires et les fichiers par ceux qui ne vous intéressent pas.

  DirectoryName("Game_I_never_play_after_installing")
    OR DirectoryName("Another_game_I_keep_but_rarely_play")
    OR DirectoryName("Game_that_takes_up_almost_half_the_HDD")
    OR Filename("vc_redist.x64.exe")
    OR Filename("vcredist_x64.exe")
    OR Filename("vcredist_x64*.exe")
    OR Filename("*.iso")
    OR Filename("*.isz")
    OR Filename("*.mdf")
    OR Filename("*.cdi")
    OR Filename("*.pdf")
    OR Filename("*.bik")
    OR Filename("*.avi")
    OR Filename("*.wmv")
    OR Filename("*.bk2")
    OR Filename("*.mp4")
    OR Filename("*.rar")
    OR Filename("*.zip")
    OR Filename("*.7z")
    OR Filename("*.7z.*")

Exécutez votre script

Avec les deux fichiers qui définissent votre logique de défragmentation prêts, il est temps de les mettre à l’épreuve ! Exécutez MyDefrag et, s’il n’y a aucune faute de frappe, votre script devrait apparaître parmi les scripts par défaut dans la liste du programme.

Sélectionnez-le dans la liste « Sélectionnez un script ». Ensuite, comme l’indique MyDefrag, « Sélectionnez 1 ou plusieurs disques » dans la deuxième liste que vous souhaitez défragmenter en fonction des règles de votre script. Cliquez sur « Exécuter » et donnez-lui quelques heures (ou jours, pour les disques durs d’un téraoctet) pour faire fonctionner sa magie.

C’est ça. Vous avez défragmenté et optimisé votre disque dur comme vous le souhaitez, et il devrait fonctionner mieux et plus rapidement maintenant.

• Que se passe-t-il lorsque vous défragmentez un lecteur ?
• 5 outils qui améliorent les performances du disque dur de Windows 10
• Comment défragmenter vos disques durs à partir du menu contextuel de Windows